CLASS {{p}}t16_test DEFINITION PUBLIC FINAL CREATE PUBLIC
  FOR TESTING DURATION SHORT RISK LEVEL HARMLESS.

  PRIVATE SECTION.
    CLASS-DATA go_env TYPE REF TO if_osql_test_environment.

    CLASS-METHODS class_setup.
    CLASS-METHODS class_teardown.
    METHODS setup.

    METHODS structure_is_correct FOR TESTING.
    METHODS booking_is_stored FOR TESTING.
    METHODS two_bookings_are_stored FOR TESTING.
    METHODS rate_keeps_decimals FOR TESTING.
ENDCLASS.


CLASS {{p}}t16_test IMPLEMENTATION.

  METHOD class_setup.
    go_env = cl_osql_test_environment=>create( i_dependency_list = VALUE #( ( '{{P}}PITCH' ) ) ).
  ENDMETHOD.

  METHOD class_teardown.
    IF go_env IS BOUND.
      go_env->destroy( ).
    ENDIF.
  ENDMETHOD.

  METHOD setup.
    go_env->clear_doubles( ).
  ENDMETHOD.

  METHOD structure_is_correct.
    DATA(lo_struct) = CAST cl_abap_structdescr( cl_abap_typedescr=>describe_by_name( '{{P}}PITCH' ) ).
    DATA(lt_fields) = lo_struct->get_ddic_field_list( ).
    cl_abap_unit_assert=>assert_equals( exp = 9 act = lines( lt_fields ) ).
    READ TABLE lt_fields INTO DATA(ls_field) WITH KEY fieldname = 'BOOKING_ID'.
    cl_abap_unit_assert=>assert_equals( exp = 0 act = sy-subrc ).
    cl_abap_unit_assert=>assert_equals( exp = 'X' act = ls_field-keyflag ).
    cl_abap_unit_assert=>assert_equals( exp = 10 act = ls_field-leng ).
  ENDMETHOD.

  METHOD booking_is_stored.
    DATA lt_rows TYPE STANDARD TABLE OF {{p}}pitch WITH EMPTY KEY.
    lt_rows = VALUE #(
      ( client = sy-mandt booking_id = 'T0001' pitch_no = '0007' guest_name = 'WEBER'
        arrival_date = '20250701' departure_date = '20250705' persons = 3
        power_hookup = 'X' rate_per_night = '15.00' ) ).
    INSERT {{p}}pitch FROM TABLE @lt_rows.
    cl_abap_unit_assert=>assert_subrc( exp = 0 ).
    SELECT SINGLE guest_name, pitch_no, persons FROM {{p}}pitch
      WHERE booking_id = 'T0001' INTO @DATA(ls_row).
    cl_abap_unit_assert=>assert_equals( exp = 'WEBER' act = ls_row-guest_name ).
    cl_abap_unit_assert=>assert_equals( exp = '0007' act = ls_row-pitch_no ).
    cl_abap_unit_assert=>assert_equals( exp = 3 act = ls_row-persons ).
  ENDMETHOD.

  METHOD two_bookings_are_stored.
    DATA lt_rows TYPE STANDARD TABLE OF {{p}}pitch WITH EMPTY KEY.
    lt_rows = VALUE #(
      ( client = sy-mandt booking_id = 'T0002' pitch_no = '0008' arrival_date = '20250701'
        departure_date = '20250705' persons = 2 rate_per_night = '15.00' )
      ( client = sy-mandt booking_id = 'T0003' pitch_no = '0009' arrival_date = '20250701'
        departure_date = '20250703' persons = 1 rate_per_night = '12.00' ) ).
    INSERT {{p}}pitch FROM TABLE @lt_rows.
    cl_abap_unit_assert=>assert_subrc( exp = 0 ).
    SELECT COUNT(*) FROM {{p}}pitch INTO @DATA(lv_count).
    cl_abap_unit_assert=>assert_equals( exp = 2 act = lv_count ).
  ENDMETHOD.

  METHOD rate_keeps_decimals.
    DATA lt_rows TYPE STANDARD TABLE OF {{p}}pitch WITH EMPTY KEY.
    lt_rows = VALUE #(
      ( client = sy-mandt booking_id = 'T0004' pitch_no = '0010' arrival_date = '20250701'
        departure_date = '20250705' persons = 1 rate_per_night = '12.34' ) ).
    INSERT {{p}}pitch FROM TABLE @lt_rows.
    cl_abap_unit_assert=>assert_subrc( exp = 0 ).
    SELECT SINGLE rate_per_night FROM {{p}}pitch WHERE booking_id = 'T0004' INTO @DATA(lv_rate).
    cl_abap_unit_assert=>assert_equals( exp = CONV decfloat34( '12.34' )
      act = CONV decfloat34( lv_rate ) ).
  ENDMETHOD.
ENDCLASS.