CLASS {{p}}t15_hidden DEFINITION PUBLIC FINAL CREATE PUBLIC
  FOR TESTING DURATION SHORT RISK LEVEL HARMLESS.
  PRIVATE SECTION.
    TYPES tt_magazine TYPE RANGE OF {{p}}subs-magazine.
    METHODS run
      IMPORTING iv_from         TYPE d
                it_magazine     TYPE tt_magazine OPTIONAL
      RETURNING VALUE(rr_data)  TYPE REF TO data.
    METHODS value_of
      IMPORTING ir_data         TYPE REF TO data
                iv_row          TYPE i
                iv_col          TYPE string
      RETURNING VALUE(rv_value) TYPE string.
    METHODS lines_of
      IMPORTING ir_data         TYPE REF TO data
      RETURNING VALUE(rv_lines) TYPE i.
    METHODS two_magazines FOR TESTING.
    METHODS sorted_by_revenue FOR TESTING.
    METHODS totals_and_counts FOR TESTING.
    METHODS cancelled_excluded FOR TESTING.
    METHODS small_group_hidden FOR TESTING.
    METHODS magazine_filter FOR TESTING.
    METHODS date_filter FOR TESTING.
    METHODS empty_result FOR TESTING.
ENDCLASS.


CLASS {{p}}t15_hidden IMPLEMENTATION.
  METHOD run.
    cl_salv_bs_runtime_info=>set( display = abap_false metadata = abap_false data = abap_true ).
    SUBMIT {{p}}subs_sum WITH p_from = iv_from WITH s_mag IN it_magazine AND RETURN.
    TRY.
        cl_salv_bs_runtime_info=>get_data_ref( IMPORTING r_data = rr_data ).
      CATCH cx_salv_bs_sc_runtime_info.
    ENDTRY.
    cl_salv_bs_runtime_info=>clear_all( ).
  ENDMETHOD.

  METHOD lines_of.
    FIELD-SYMBOLS <lt_data> TYPE STANDARD TABLE.
    IF ir_data IS BOUND.
      ASSIGN ir_data->* TO <lt_data>.
      rv_lines = lines( <lt_data> ).
    ENDIF.
  ENDMETHOD.

  METHOD value_of.
    FIELD-SYMBOLS <lt_data> TYPE STANDARD TABLE.
    ASSIGN ir_data->* TO <lt_data>.
    ASSIGN <lt_data>[ iv_row ] TO FIELD-SYMBOL(<ls_line>).
    ASSIGN COMPONENT iv_col OF STRUCTURE <ls_line> TO FIELD-SYMBOL(<lv_value>).
    cl_abap_unit_assert=>assert_subrc( exp = 0 msg = |Column { iv_col } missing| ).
    rv_value = condense( CONV string( <lv_value> ) ).
  ENDMETHOD.

  METHOD two_magazines.
    cl_abap_unit_assert=>assert_equals( exp = 2 act = lines_of( run( '20260101' ) ) ).
  ENDMETHOD.

  METHOD sorted_by_revenue.
    DATA(lr_data) = run( '20260101' ).
    cl_abap_unit_assert=>assert_equals( exp = `NATURE` act = value_of( ir_data = lr_data iv_row = 1 iv_col = `MAGAZINE` ) ).
    cl_abap_unit_assert=>assert_equals( exp = `ORBIT` act = value_of( ir_data = lr_data iv_row = 2 iv_col = `MAGAZINE` ) ).
  ENDMETHOD.

  METHOD totals_and_counts.
    DATA(lr_data) = run( '20260101' ).
    cl_abap_unit_assert=>assert_equals( exp = `40.00` act = value_of( ir_data = lr_data iv_row = 1 iv_col = `REVENUE` ) ).
    cl_abap_unit_assert=>assert_equals( exp = `2` act = value_of( ir_data = lr_data iv_row = 1 iv_col = `NUM_SUBS` ) ).
  ENDMETHOD.

  METHOD cancelled_excluded.
    DATA(lr_data) = run( '20260101' ).
    cl_abap_unit_assert=>assert_equals( exp = `20.00` act = value_of( ir_data = lr_data iv_row = 2 iv_col = `REVENUE` ) ).
  ENDMETHOD.

  METHOD small_group_hidden.
    DATA(lr_data) = run( iv_from = '20260101'
                         it_magazine = VALUE #( ( sign = 'I' option = 'EQ' low = 'SPORT' ) ) ).
    cl_abap_unit_assert=>assert_equals( exp = 0 act = lines_of( lr_data ) ).
  ENDMETHOD.

  METHOD magazine_filter.
    DATA(lr_data) = run( iv_from = '20260101'
                         it_magazine = VALUE #( ( sign = 'I' option = 'EQ' low = 'NATURE' ) ) ).
    cl_abap_unit_assert=>assert_equals( exp = 1 act = lines_of( lr_data ) ).
    cl_abap_unit_assert=>assert_equals( exp = `NATURE` act = value_of( ir_data = lr_data iv_row = 1 iv_col = `MAGAZINE` ) ).
    cl_abap_unit_assert=>assert_equals( exp = `40.00` act = value_of( ir_data = lr_data iv_row = 1 iv_col = `REVENUE` ) ).
  ENDMETHOD.

  METHOD date_filter.
    DATA(lr_data) = run( '20251201' ).
    cl_abap_unit_assert=>assert_equals( exp = `45.00` act = value_of( ir_data = lr_data iv_row = 1 iv_col = `REVENUE` ) ).
    cl_abap_unit_assert=>assert_equals( exp = `3` act = value_of( ir_data = lr_data iv_row = 1 iv_col = `NUM_SUBS` ) ).
  ENDMETHOD.

  METHOD empty_result.
    cl_abap_unit_assert=>assert_equals( exp = 0 act = lines_of( run( '20260201' ) ) ).
  ENDMETHOD.
ENDCLASS.