CLASS {{p}}t16_hidden DEFINITION PUBLIC FINAL CREATE PUBLIC
  FOR TESTING DURATION SHORT RISK LEVEL HARMLESS.
  PRIVATE SECTION.
    CONSTANTS c_from TYPE d VALUE '20240101'.
    CONSTANTS c_to   TYPE d VALUE '20240131'.
    CLASS-DATA go_env TYPE REF TO if_cds_test_environment.
    CLASS-METHODS class_setup.
    CLASS-METHODS class_teardown.
    METHODS setup.
    METHODS row_per_product FOR TESTING.
    METHODS sums_quantity FOR TESTING.
    METHODS sums_amount FOR TESTING.
    METHODS excludes_before_from FOR TESTING.
    METHODS excludes_after_to FOR TESTING.
    METHODS bounds_inclusive FOR TESTING.
    METHODS empty_period FOR TESTING.
ENDCLASS.


CLASS {{p}}t16_hidden IMPLEMENTATION.
  METHOD class_setup.
    go_env = cl_cds_test_environment=>create( i_for_entity = '{{P}}I_SALES_REPORT' ).
  ENDMETHOD.

  METHOD class_teardown.
    go_env->destroy( ).
  ENDMETHOD.

  METHOD setup.
    DATA lt_sales TYPE STANDARD TABLE OF {{p}}sales WITH EMPTY KEY.
    go_env->clear_doubles( ).
    lt_sales = VALUE #(
      ( doc_id = 'D1' item_no = 1 product = 'MAT_A' quantity = 3 price = '10.00'  sold_on = '20240110' )
      ( doc_id = 'D1' item_no = 2 product = 'MAT_A' quantity = 2 price = '5.00'   sold_on = '20240115' )
      ( doc_id = 'D2' item_no = 1 product = 'MAT_B' quantity = 1 price = '100.00' sold_on = '20240131' )
      ( doc_id = 'D3' item_no = 1 product = 'MAT_B' quantity = 4 price = '2.50'   sold_on = '20231231' )
      ( doc_id = 'D4' item_no = 1 product = 'MAT_C' quantity = 7 price = '1.00'   sold_on = '20240201' ) ).
    go_env->insert_test_data( lt_sales ).
  ENDMETHOD.

  METHOD row_per_product.
    SELECT COUNT(*) FROM {{p}}i_sales_report( p_from = @c_from, p_to = @c_to )
      INTO @DATA(lv_rows).
    cl_abap_unit_assert=>assert_equals( exp = 2 act = lv_rows ).
  ENDMETHOD.

  METHOD sums_quantity.
    SELECT SINGLE total_qty FROM {{p}}i_sales_report( p_from = @c_from, p_to = @c_to )
      WHERE product = 'MAT_A' INTO @DATA(lv_qty).
    cl_abap_unit_assert=>assert_equals( exp = 5 act = lv_qty ).
  ENDMETHOD.

  METHOD sums_amount.
    SELECT SINGLE total_amount FROM {{p}}i_sales_report( p_from = @c_from, p_to = @c_to )
      WHERE product = 'MAT_A' INTO @DATA(lv_amount).
    cl_abap_unit_assert=>assert_equals( exp = CONV decfloat34( '40.00' )
                                        act = CONV decfloat34( lv_amount ) ).
  ENDMETHOD.

  METHOD excludes_before_from.
    SELECT SINGLE total_qty FROM {{p}}i_sales_report( p_from = @c_from, p_to = @c_to )
      WHERE product = 'MAT_B' INTO @DATA(lv_qty).
    cl_abap_unit_assert=>assert_equals( exp = 1 act = lv_qty ).
  ENDMETHOD.

  METHOD excludes_after_to.
    SELECT COUNT(*) FROM {{p}}i_sales_report( p_from = @c_from, p_to = @c_to )
      WHERE product = 'MAT_C' INTO @DATA(lv_rows).
    cl_abap_unit_assert=>assert_equals( exp = 0 act = lv_rows ).
  ENDMETHOD.

  METHOD bounds_inclusive.
    DATA lv_day TYPE d.
    lv_day = '20240131'.
    SELECT SINGLE total_qty FROM {{p}}i_sales_report( p_from = @lv_day, p_to = @lv_day )
      WHERE product = 'MAT_B' INTO @DATA(lv_qty).
    cl_abap_unit_assert=>assert_equals( exp = 1 act = lv_qty ).
  ENDMETHOD.

  METHOD empty_period.
    DATA lv_from TYPE d.
    DATA lv_to TYPE d.
    lv_from = '20230101'.
    lv_to = '20230131'.
    SELECT COUNT(*) FROM {{p}}i_sales_report( p_from = @lv_from, p_to = @lv_to )
      INTO @DATA(lv_rows).
    cl_abap_unit_assert=>assert_equals( exp = 0 act = lv_rows ).
  ENDMETHOD.
ENDCLASS.