CLASS {{p}}t41_test DEFINITION PUBLIC FINAL CREATE PUBLIC
  FOR TESTING DURATION SHORT RISK LEVEL HARMLESS.
  PRIVATE SECTION.
    CLASS-DATA go_env TYPE REF TO if_cds_test_environment.
    CLASS-METHODS class_setup.
    CLASS-METHODS class_teardown.
    METHODS setup.
    METHODS stats_of_one_album FOR TESTING.
ENDCLASS.


CLASS {{p}}t41_test IMPLEMENTATION.
  METHOD class_setup.
    go_env = cl_cds_test_environment=>create( i_for_entity = '{{P}}I_ALBUM_STATS' ).
  ENDMETHOD.

  METHOD class_teardown.
    go_env->destroy( ).
  ENDMETHOD.

  METHOD setup.
    go_env->clear_doubles( ).
  ENDMETHOD.

  METHOD stats_of_one_album.
    DATA lt_album TYPE STANDARD TABLE OF {{p}}album WITH EMPTY KEY.
    DATA lt_track TYPE STANDARD TABLE OF {{p}}track WITH EMPTY KEY.
    lt_album = VALUE #( ( album_id = 'B1' title = 'SOLO' artist = 'ONE' ) ).
    lt_track = VALUE #( ( album_id = 'B1' track_no = 1 play_sec = 100 genre = 'POP' )
                        ( album_id = 'B1' track_no = 2 play_sec = 250 genre = 'POP' ) ).
    go_env->insert_test_data( lt_album ).
    go_env->insert_test_data( lt_track ).
    SELECT SINGLE track_count, total_seconds, longest_seconds FROM {{p}}i_album_stats
      WHERE album_id = 'B1' INTO @DATA(ls_stat).
    cl_abap_unit_assert=>assert_equals( exp = CONV decfloat34( 2 )
                                        act = CONV decfloat34( ls_stat-track_count ) ).
    cl_abap_unit_assert=>assert_equals( exp = CONV decfloat34( 350 )
                                        act = CONV decfloat34( ls_stat-total_seconds ) ).
    cl_abap_unit_assert=>assert_equals( exp = CONV decfloat34( 250 )
                                        act = CONV decfloat34( ls_stat-longest_seconds ) ).
  ENDMETHOD.
ENDCLASS.