CLASS {{p}}bill_age_test DEFINITION PUBLIC FINAL CREATE PUBLIC
  FOR TESTING DURATION SHORT RISK LEVEL HARMLESS.
  PRIVATE SECTION.
    TYPES tt_customer TYPE RANGE OF {{p}}bill-customer.
    METHODS run
      IMPORTING iv_date         TYPE d
                it_customer     TYPE tt_customer OPTIONAL
      RETURNING VALUE(rr_data)  TYPE REF TO data.
    METHODS value_of
      IMPORTING ir_data         TYPE REF TO data
                iv_row          TYPE i
                iv_col          TYPE string
      RETURNING VALUE(rv_value) TYPE string.
    METHODS lines_of
      IMPORTING ir_data         TYPE REF TO data
      RETURNING VALUE(rv_lines) TYPE i.
    METHODS only_open_invoices FOR TESTING.
    METHODS paid_invoices_excluded FOR TESTING.
    METHODS sorted_by_open_amount FOR TESTING.
    METHODS count_and_amount FOR TESTING.
    METHODS overdue_amount FOR TESTING.
    METHODS no_overdue_amount FOR TESTING.
    METHODS customer_filter FOR TESTING.
    METHODS customer_filter_multiple FOR TESTING.
ENDCLASS.


CLASS {{p}}bill_age_test IMPLEMENTATION.
  METHOD run.
    cl_salv_bs_runtime_info=>set( display = abap_false metadata = abap_false data = abap_true ).
    SUBMIT {{p}}bill_age WITH p_date = iv_date WITH s_cust IN it_customer AND RETURN.
    TRY.
        cl_salv_bs_runtime_info=>get_data_ref( IMPORTING r_data = rr_data ).
      CATCH cx_salv_bs_sc_runtime_info.
    ENDTRY.
    cl_salv_bs_runtime_info=>clear_all( ).
  ENDMETHOD.

  METHOD lines_of.
    FIELD-SYMBOLS <lt_data> TYPE STANDARD TABLE.
    IF ir_data IS BOUND.
      ASSIGN ir_data->* TO <lt_data>.
      rv_lines = lines( <lt_data> ).
    ENDIF.
  ENDMETHOD.

  METHOD value_of.
    FIELD-SYMBOLS <lt_data> TYPE STANDARD TABLE.
    ASSIGN ir_data->* TO <lt_data>.
    ASSIGN <lt_data>[ iv_row ] TO FIELD-SYMBOL(<ls_line>).
    ASSIGN COMPONENT iv_col OF STRUCTURE <ls_line> TO FIELD-SYMBOL(<lv_value>).
    cl_abap_unit_assert=>assert_subrc( exp = 0 msg = |Column { iv_col } is missing| ).
    rv_value = condense( CONV string( <lv_value> ) ).
  ENDMETHOD.

  METHOD only_open_invoices.
    cl_abap_unit_assert=>assert_equals( exp = 4 act = lines_of( run( '20260101' ) ) ).
  ENDMETHOD.

  METHOD paid_invoices_excluded.
    DATA(lr_data) = run( '20260101' ).
    cl_abap_unit_assert=>assert_equals( exp = `C002`
      act = value_of( ir_data = lr_data iv_row = 2 iv_col = `CUSTOMER` ) ).
    cl_abap_unit_assert=>assert_equals( exp = `300.00`
      act = value_of( ir_data = lr_data iv_row = 2 iv_col = `OPEN_AMOUNT` ) ).
  ENDMETHOD.

  METHOD sorted_by_open_amount.
    DATA(lr_data) = run( '20260101' ).
    cl_abap_unit_assert=>assert_equals( exp = `C004`
      act = value_of( ir_data = lr_data iv_row = 1 iv_col = `CUSTOMER` ) ).
    cl_abap_unit_assert=>assert_equals( exp = `C003`
      act = value_of( ir_data = lr_data iv_row = 4 iv_col = `CUSTOMER` ) ).
  ENDMETHOD.

  METHOD count_and_amount.
    DATA(lr_data) = run( '20260101' ).
    cl_abap_unit_assert=>assert_equals( exp = `C001`
      act = value_of( ir_data = lr_data iv_row = 3 iv_col = `CUSTOMER` ) ).
    cl_abap_unit_assert=>assert_equals( exp = `2`
      act = value_of( ir_data = lr_data iv_row = 3 iv_col = `OPEN_COUNT` ) ).
    cl_abap_unit_assert=>assert_equals( exp = `150.00`
      act = value_of( ir_data = lr_data iv_row = 3 iv_col = `OPEN_AMOUNT` ) ).
  ENDMETHOD.

  METHOD overdue_amount.
    DATA(lr_data) = run( '20260301' ).
    cl_abap_unit_assert=>assert_equals( exp = `100.00`
      act = value_of( ir_data = lr_data iv_row = 3 iv_col = `OVERDUE_AMOUNT` ) ).
    cl_abap_unit_assert=>assert_equals( exp = `300.00`
      act = value_of( ir_data = lr_data iv_row = 2 iv_col = `OVERDUE_AMOUNT` ) ).
  ENDMETHOD.

  METHOD no_overdue_amount.
    DATA(lr_data) = run( '20260101' ).
    cl_abap_unit_assert=>assert_equals( exp = `0.00`
      act = value_of( ir_data = lr_data iv_row = 1 iv_col = `OVERDUE_AMOUNT` ) ).
    cl_abap_unit_assert=>assert_equals( exp = `0.00`
      act = value_of( ir_data = lr_data iv_row = 3 iv_col = `OVERDUE_AMOUNT` ) ).
  ENDMETHOD.

  METHOD customer_filter.
    DATA(lr_data) = run( iv_date = '20260101'
                         it_customer = VALUE #( ( sign = 'I' option = 'EQ' low = 'C001' ) ) ).
    cl_abap_unit_assert=>assert_equals( exp = 1 act = lines_of( lr_data ) ).
    cl_abap_unit_assert=>assert_equals( exp = `150.00`
      act = value_of( ir_data = lr_data iv_row = 1 iv_col = `OPEN_AMOUNT` ) ).
  ENDMETHOD.

  METHOD customer_filter_multiple.
    DATA(lr_data) = run( iv_date = '20260101'
                         it_customer = VALUE #( ( sign = 'I' option = 'EQ' low = 'C001' )
                                                ( sign = 'I' option = 'EQ' low = 'C002' ) ) ).
    cl_abap_unit_assert=>assert_equals( exp = 2 act = lines_of( lr_data ) ).
    cl_abap_unit_assert=>assert_equals( exp = `C002`
      act = value_of( ir_data = lr_data iv_row = 1 iv_col = `CUSTOMER` ) ).
    cl_abap_unit_assert=>assert_equals( exp = `C001`
      act = value_of( ir_data = lr_data iv_row = 2 iv_col = `CUSTOMER` ) ).
  ENDMETHOD.
ENDCLASS.