CLASS {{p}}t_dive_stats_test DEFINITION PUBLIC FINAL CREATE PUBLIC
  FOR TESTING DURATION SHORT RISK LEVEL HARMLESS.
  PRIVATE SECTION.
    CLASS-DATA go_env TYPE REF TO if_cds_test_environment.
    CLASS-METHODS class_setup.
    CLASS-METHODS class_teardown.
    METHODS setup.
    METHODS stats_of_one_diver FOR TESTING.
ENDCLASS.

CLASS {{p}}t_dive_stats_test IMPLEMENTATION.
  METHOD class_setup.
    go_env = cl_cds_test_environment=>create( i_for_entity = '{{P}}I_DIVE_STATS' ).
  ENDMETHOD.

  METHOD class_teardown.
    go_env->destroy( ).
  ENDMETHOD.

  METHOD setup.
    DATA lt_diver TYPE STANDARD TABLE OF {{p}}diver WITH EMPTY KEY.
    DATA lt_site TYPE STANDARD TABLE OF {{p}}site WITH EMPTY KEY.
    DATA lt_dive TYPE STANDARD TABLE OF {{p}}dive WITH EMPTY KEY.
    go_env->clear_doubles( ).
    lt_diver = VALUE #( ( diver_id = 'X1' diver_name = 'Test' ) ).
    lt_site = VALUE #( ( site_id = 'S1' site_name = 'Reef' depth_m = 12 ) ).
    lt_dive = VALUE #(
      ( dive_id = 'V1' diver_id = 'X1' site_id = 'S1' dive_date = '20250101' )
      ( dive_id = 'V2' diver_id = 'X1' site_id = 'S1' dive_date = '20250102' ) ).
    go_env->insert_test_data( lt_diver ).
    go_env->insert_test_data( lt_site ).
    go_env->insert_test_data( lt_dive ).
  ENDMETHOD.

  METHOD stats_of_one_diver.
    SELECT SINGLE dive_count, deepest_m FROM {{p}}i_dive_stats WHERE diver_id = 'X1'
      INTO @DATA(ls_row).
    cl_abap_unit_assert=>assert_equals( exp = 2 act = ls_row-dive_count ).
    cl_abap_unit_assert=>assert_equals( exp = 12 act = ls_row-deepest_m ).
  ENDMETHOD.
ENDCLASS.