CLASS {{p}}t15_test DEFINITION PUBLIC FINAL CREATE PUBLIC
  FOR TESTING DURATION SHORT RISK LEVEL HARMLESS.
  PRIVATE SECTION.
    CLASS-DATA go_env TYPE REF TO if_cds_test_environment.
    CLASS-METHODS class_setup.
    CLASS-METHODS class_teardown.
    METHODS setup.
    METHODS total_of_one_order FOR TESTING.
ENDCLASS.


CLASS {{p}}t15_test IMPLEMENTATION.
  METHOD class_setup.
    go_env = cl_cds_test_environment=>create( i_for_entity = '{{P}}I_ORDER_TOTAL' ).
  ENDMETHOD.

  METHOD class_teardown.
    go_env->destroy( ).
  ENDMETHOD.

  METHOD setup.
    go_env->clear_doubles( ).
  ENDMETHOD.

  METHOD total_of_one_order.
    DATA lt_ord TYPE STANDARD TABLE OF {{p}}ord WITH EMPTY KEY.
    DATA lt_itm TYPE STANDARD TABLE OF {{p}}itm WITH EMPTY KEY.
    lt_ord = VALUE #( ( order_id = 'A' customer = 'C1' ) ).
    lt_itm = VALUE #( ( order_id = 'A' item_no = 1 quantity = 2 price = '1.50' )
                      ( order_id = 'A' item_no = 2 quantity = 1 price = '4.00' ) ).
    go_env->insert_test_data( lt_ord ).
    go_env->insert_test_data( lt_itm ).
    SELECT SINGLE item_count, total_amount FROM {{p}}i_order_total WHERE order_id = 'A'
      INTO @DATA(ls_total).
    cl_abap_unit_assert=>assert_equals( exp = 2 act = ls_total-item_count ).
    cl_abap_unit_assert=>assert_equals( exp = CONV decfloat34( 7 ) act = CONV decfloat34( ls_total-total_amount ) ).
  ENDMETHOD.
ENDCLASS.