118 lines
4.8 KiB
ABAP
118 lines
4.8 KiB
ABAP
CLASS {{p}}scrap_hidden DEFINITION PUBLIC FINAL CREATE PUBLIC
|
|
FOR TESTING DURATION SHORT RISK LEVEL HARMLESS.
|
|
PRIVATE SECTION.
|
|
TYPES tt_metal TYPE RANGE OF {{p}}scrap-metal.
|
|
|
|
METHODS run_report
|
|
IMPORTING iv_date TYPE d
|
|
it_metal TYPE tt_metal OPTIONAL
|
|
RETURNING VALUE(rr_data) TYPE REF TO data.
|
|
|
|
METHODS lines_of
|
|
IMPORTING ir_data TYPE REF TO data
|
|
RETURNING VALUE(rv_lines) TYPE i.
|
|
|
|
METHODS value_of
|
|
IMPORTING ir_data TYPE REF TO data
|
|
iv_row TYPE i
|
|
iv_col TYPE string
|
|
RETURNING VALUE(rv_value) TYPE string.
|
|
|
|
METHODS all_metals FOR TESTING.
|
|
METHODS sorted_by_pay FOR TESTING.
|
|
METHODS bonus_over_limit FOR TESTING.
|
|
METHODS bonus_at_limit FOR TESTING.
|
|
METHODS no_bonus_below_limit FOR TESTING.
|
|
METHODS metal_filter FOR TESTING.
|
|
METHODS date_filter FOR TESTING.
|
|
METHODS counts FOR TESTING.
|
|
METHODS empty_result FOR TESTING.
|
|
ENDCLASS.
|
|
|
|
|
|
CLASS {{p}}scrap_hidden IMPLEMENTATION.
|
|
METHOD run_report.
|
|
cl_salv_bs_runtime_info=>set( display = abap_false
|
|
metadata = abap_false
|
|
data = abap_true ).
|
|
SUBMIT {{p}}scrap_pay WITH p_date = iv_date WITH s_metal IN it_metal AND RETURN.
|
|
TRY.
|
|
cl_salv_bs_runtime_info=>get_data_ref( IMPORTING r_data = rr_data ).
|
|
CATCH cx_salv_bs_sc_runtime_info.
|
|
ENDTRY.
|
|
cl_salv_bs_runtime_info=>clear_all( ).
|
|
ENDMETHOD.
|
|
|
|
METHOD lines_of.
|
|
FIELD-SYMBOLS <lt_data> TYPE STANDARD TABLE.
|
|
IF ir_data IS BOUND.
|
|
ASSIGN ir_data->* TO <lt_data>.
|
|
rv_lines = lines( <lt_data> ).
|
|
ENDIF.
|
|
ENDMETHOD.
|
|
|
|
METHOD value_of.
|
|
FIELD-SYMBOLS <lt_data> TYPE STANDARD TABLE.
|
|
IF ir_data IS NOT BOUND.
|
|
cl_abap_unit_assert=>fail( msg = 'No ALV data' ).
|
|
ENDIF.
|
|
ASSIGN ir_data->* TO <lt_data>.
|
|
ASSIGN <lt_data>[ iv_row ] TO FIELD-SYMBOL(<ls_line>).
|
|
ASSIGN COMPONENT iv_col OF STRUCTURE <ls_line> TO FIELD-SYMBOL(<lv_value>).
|
|
cl_abap_unit_assert=>assert_subrc( exp = 0 msg = |Column { iv_col } is missing| ).
|
|
rv_value = condense( CONV string( <lv_value> ) ).
|
|
ENDMETHOD.
|
|
|
|
METHOD all_metals.
|
|
cl_abap_unit_assert=>assert_equals( exp = 4 act = lines_of( run_report( '20260115' ) ) ).
|
|
ENDMETHOD.
|
|
|
|
METHOD sorted_by_pay.
|
|
DATA(lr_data) = run_report( '20260115' ).
|
|
cl_abap_unit_assert=>assert_equals( exp = `CU` act = value_of( ir_data = lr_data iv_row = 1 iv_col = `METAL` ) ).
|
|
cl_abap_unit_assert=>assert_equals( exp = `BR` act = value_of( ir_data = lr_data iv_row = 4 iv_col = `METAL` ) ).
|
|
ENDMETHOD.
|
|
|
|
METHOD bonus_over_limit.
|
|
DATA(lr_data) = run_report( '20260115' ).
|
|
cl_abap_unit_assert=>assert_equals( exp = `3630.00` act = value_of( ir_data = lr_data iv_row = 1 iv_col = `TOTAL_PAY` ) ).
|
|
cl_abap_unit_assert=>assert_equals( exp = `550.000` act = value_of( ir_data = lr_data iv_row = 1 iv_col = `TOTAL_KG` ) ).
|
|
ENDMETHOD.
|
|
|
|
METHOD bonus_at_limit.
|
|
DATA(lr_data) = run_report( '20260115' ).
|
|
cl_abap_unit_assert=>assert_equals( exp = `759.00` act = value_of( ir_data = lr_data iv_row = 2 iv_col = `TOTAL_PAY` ) ).
|
|
cl_abap_unit_assert=>assert_equals( exp = `500.000` act = value_of( ir_data = lr_data iv_row = 2 iv_col = `TOTAL_KG` ) ).
|
|
ENDMETHOD.
|
|
|
|
METHOD no_bonus_below_limit.
|
|
DATA(lr_data) = run_report( '20260115' ).
|
|
cl_abap_unit_assert=>assert_equals( exp = `80.00` act = value_of( ir_data = lr_data iv_row = 3 iv_col = `TOTAL_PAY` ) ).
|
|
cl_abap_unit_assert=>assert_equals( exp = `60.00` act = value_of( ir_data = lr_data iv_row = 4 iv_col = `TOTAL_PAY` ) ).
|
|
ENDMETHOD.
|
|
|
|
METHOD metal_filter.
|
|
DATA(lr_data) = run_report( iv_date = '20260115'
|
|
it_metal = VALUE #( ( sign = 'I' option = 'EQ' low = 'CU' ) ) ).
|
|
cl_abap_unit_assert=>assert_equals( exp = 1 act = lines_of( lr_data ) ).
|
|
cl_abap_unit_assert=>assert_equals( exp = `3630.00` act = value_of( ir_data = lr_data iv_row = 1 iv_col = `TOTAL_PAY` ) ).
|
|
ENDMETHOD.
|
|
|
|
METHOD date_filter.
|
|
DATA(lr_data) = run_report( '20260110' ).
|
|
cl_abap_unit_assert=>assert_equals( exp = 2 act = lines_of( lr_data ) ).
|
|
cl_abap_unit_assert=>assert_equals( exp = `3300.00` act = value_of( ir_data = lr_data iv_row = 1 iv_col = `TOTAL_PAY` ) ).
|
|
cl_abap_unit_assert=>assert_equals( exp = `30.00` act = value_of( ir_data = lr_data iv_row = 2 iv_col = `TOTAL_PAY` ) ).
|
|
ENDMETHOD.
|
|
|
|
METHOD counts.
|
|
DATA(lr_data) = run_report( '20260115' ).
|
|
cl_abap_unit_assert=>assert_equals( exp = `2` act = value_of( ir_data = lr_data iv_row = 1 iv_col = `DELIV_CNT` ) ).
|
|
cl_abap_unit_assert=>assert_equals( exp = `3` act = value_of( ir_data = lr_data iv_row = 2 iv_col = `DELIV_CNT` ) ).
|
|
ENDMETHOD.
|
|
|
|
METHOD empty_result.
|
|
cl_abap_unit_assert=>assert_equals( exp = 0 act = lines_of( run_report( '20261231' ) ) ).
|
|
ENDMETHOD.
|
|
ENDCLASS.
|