57 lines
2.4 KiB
ABAP
57 lines
2.4 KiB
ABAP
CLASS {{p}}t16_test DEFINITION PUBLIC FINAL CREATE PUBLIC
|
|
FOR TESTING DURATION SHORT RISK LEVEL HARMLESS.
|
|
PRIVATE SECTION.
|
|
CLASS-DATA go_env TYPE REF TO if_cds_test_environment.
|
|
CLASS-METHODS class_setup.
|
|
CLASS-METHODS class_teardown.
|
|
METHODS setup.
|
|
METHODS low_machine FOR TESTING.
|
|
METHODS empty_machine FOR TESTING.
|
|
ENDCLASS.
|
|
|
|
|
|
CLASS {{p}}t16_test IMPLEMENTATION.
|
|
METHOD class_setup.
|
|
go_env = cl_cds_test_environment=>create( i_for_entity = '{{P}}I_VEND_STATE' ).
|
|
ENDMETHOD.
|
|
|
|
METHOD class_teardown.
|
|
go_env->destroy( ).
|
|
ENDMETHOD.
|
|
|
|
METHOD setup.
|
|
go_env->clear_doubles( ).
|
|
ENDMETHOD.
|
|
|
|
METHOD low_machine.
|
|
DATA lt_mach TYPE STANDARD TABLE OF {{p}}vmach WITH EMPTY KEY.
|
|
DATA lt_slot TYPE STANDARD TABLE OF {{p}}vslot WITH EMPTY KEY.
|
|
lt_mach = VALUE #( ( machine_id = 'A' location = 'Hall' ) ).
|
|
lt_slot = VALUE #( ( machine_id = 'A' slot_no = 1 product = 'COLA' fill_level = 1 max_units = 4 )
|
|
( machine_id = 'A' slot_no = 2 product = 'TEA' fill_level = 0 max_units = 4 ) ).
|
|
go_env->insert_test_data( lt_mach ).
|
|
go_env->insert_test_data( lt_slot ).
|
|
SELECT SINGLE slot_count, empty_slots, fill_rate, status FROM {{p}}i_vend_state
|
|
WHERE machine_id = 'A' INTO @DATA(ls_row).
|
|
cl_abap_unit_assert=>assert_equals( exp = 2 act = ls_row-slot_count ).
|
|
cl_abap_unit_assert=>assert_equals( exp = 1 act = ls_row-empty_slots ).
|
|
cl_abap_unit_assert=>assert_equals( exp = CONV decfloat34( '12.5' )
|
|
act = CONV decfloat34( ls_row-fill_rate ) ).
|
|
cl_abap_unit_assert=>assert_equals( exp = 'LOW' act = ls_row-status ).
|
|
ENDMETHOD.
|
|
|
|
METHOD empty_machine.
|
|
DATA lt_mach TYPE STANDARD TABLE OF {{p}}vmach WITH EMPTY KEY.
|
|
DATA lt_slot TYPE STANDARD TABLE OF {{p}}vslot WITH EMPTY KEY.
|
|
lt_mach = VALUE #( ( machine_id = 'B' location = 'Gate' ) ).
|
|
lt_slot = VALUE #( ( machine_id = 'B' slot_no = 1 product = 'NUTS' fill_level = 0 max_units = 6 ) ).
|
|
go_env->insert_test_data( lt_mach ).
|
|
go_env->insert_test_data( lt_slot ).
|
|
SELECT SINGLE fill_rate, status FROM {{p}}i_vend_state
|
|
WHERE machine_id = 'B' INTO @DATA(ls_row).
|
|
cl_abap_unit_assert=>assert_equals( exp = CONV decfloat34( '0.0' )
|
|
act = CONV decfloat34( ls_row-fill_rate ) ).
|
|
cl_abap_unit_assert=>assert_equals( exp = 'EMPTY' act = ls_row-status ).
|
|
ENDMETHOD.
|
|
ENDCLASS.
|