106 lines
3.9 KiB
ABAP
106 lines
3.9 KiB
ABAP
REPORT {{p}}oil_report.
|
|
|
|
DATA gv_region TYPE {{p}}grove-region.
|
|
|
|
PARAMETERS p_from TYPE d OBLIGATORY.
|
|
SELECT-OPTIONS s_reg FOR gv_region.
|
|
|
|
CLASS lcl_report DEFINITION FINAL.
|
|
PUBLIC SECTION.
|
|
TYPES:
|
|
BEGIN OF ty_line,
|
|
region TYPE {{p}}grove-region,
|
|
litres TYPE {{p}}press-litres,
|
|
kilos TYPE {{p}}press-kilos,
|
|
END OF ty_line,
|
|
tt_line TYPE STANDARD TABLE OF ty_line WITH EMPTY KEY.
|
|
TYPES tt_region TYPE RANGE OF {{p}}grove-region.
|
|
METHODS collect
|
|
IMPORTING iv_from TYPE d
|
|
it_region TYPE tt_region
|
|
RETURNING VALUE(rt_lines) TYPE tt_line.
|
|
METHODS show
|
|
CHANGING ct_lines TYPE tt_line.
|
|
ENDCLASS.
|
|
|
|
CLASS lcl_report IMPLEMENTATION.
|
|
METHOD collect.
|
|
SELECT gr~region,
|
|
SUM( pr~litres ) AS litres,
|
|
SUM( pr~kilos ) AS kilos
|
|
FROM {{p}}press AS pr
|
|
INNER JOIN {{p}}grove AS gr ON gr~grove_id = pr~grove_id
|
|
WHERE pr~press_date >= @iv_from
|
|
AND gr~region IN @it_region
|
|
GROUP BY gr~region
|
|
ORDER BY litres DESCENDING
|
|
INTO CORRESPONDING FIELDS OF TABLE @rt_lines.
|
|
ENDMETHOD.
|
|
|
|
METHOD show.
|
|
TRY.
|
|
cl_salv_table=>factory( IMPORTING r_salv_table = DATA(lo_alv)
|
|
CHANGING t_table = ct_lines ).
|
|
lo_alv->display( ).
|
|
CATCH cx_salv_msg INTO DATA(lx_error).
|
|
MESSAGE lx_error TYPE 'I' DISPLAY LIKE 'E'.
|
|
ENDTRY.
|
|
ENDMETHOD.
|
|
ENDCLASS.
|
|
|
|
START-OF-SELECTION.
|
|
DATA(go_report) = NEW lcl_report( ).
|
|
DATA(gt_lines) = go_report->collect( iv_from = p_from it_region = s_reg[] ).
|
|
go_report->show( CHANGING ct_lines = gt_lines ).
|
|
|
|
CLASS ltc_report DEFINITION FINAL FOR TESTING DURATION SHORT RISK LEVEL HARMLESS.
|
|
PRIVATE SECTION.
|
|
CLASS-DATA go_env TYPE REF TO if_osql_test_environment.
|
|
CLASS-METHODS class_setup.
|
|
CLASS-METHODS class_teardown.
|
|
METHODS litres_per_region FOR TESTING.
|
|
METHODS region_filter FOR TESTING.
|
|
ENDCLASS.
|
|
|
|
CLASS ltc_report IMPLEMENTATION.
|
|
METHOD class_setup.
|
|
go_env = cl_osql_test_environment=>create(
|
|
i_dependency_list = VALUE #( ( '{{P}}GROVE' ) ( '{{P}}PRESS' ) ) ).
|
|
DATA lt_grove TYPE STANDARD TABLE OF {{p}}grove WITH EMPTY KEY.
|
|
lt_grove = VALUE #( ( grove_id = 1 grove_name = 'A' region = 'NORTH' variety = 'ARBEQ' )
|
|
( grove_id = 2 grove_name = 'B' region = 'NORTH' variety = 'ARBEQ' )
|
|
( grove_id = 3 grove_name = 'C' region = 'SOUTH' variety = 'PICUA' ) ).
|
|
go_env->insert_test_data( lt_grove ).
|
|
DATA lt_press TYPE STANDARD TABLE OF {{p}}press WITH EMPTY KEY.
|
|
lt_press = VALUE #( ( press_id = 1 grove_id = 1 press_date = '20260110' kilos = 1000 litres = '200.00' )
|
|
( press_id = 2 grove_id = 2 press_date = '20260111' kilos = 500 litres = '90.00' )
|
|
( press_id = 3 grove_id = 3 press_date = '20260112' kilos = 800 litres = '150.00' ) ).
|
|
go_env->insert_test_data( lt_press ).
|
|
ENDMETHOD.
|
|
|
|
METHOD class_teardown.
|
|
go_env->destroy( ).
|
|
ENDMETHOD.
|
|
|
|
METHOD litres_per_region.
|
|
DATA lv_expected TYPE {{p}}press-litres.
|
|
lv_expected = '290.00'.
|
|
DATA(lt_lines) = NEW lcl_report( )->collect(
|
|
iv_from = '20260101' it_region = VALUE #( ) ).
|
|
cl_abap_unit_assert=>assert_equals( exp = 2 act = lines( lt_lines ) ).
|
|
cl_abap_unit_assert=>assert_equals( exp = 'NORTH' act = lt_lines[ 1 ]-region ).
|
|
cl_abap_unit_assert=>assert_equals( exp = lv_expected act = lt_lines[ 1 ]-litres ).
|
|
cl_abap_unit_assert=>assert_equals( exp = 1500 act = lt_lines[ 1 ]-kilos ).
|
|
ENDMETHOD.
|
|
|
|
METHOD region_filter.
|
|
DATA lv_expected TYPE {{p}}press-litres.
|
|
lv_expected = '150.00'.
|
|
DATA(lt_lines) = NEW lcl_report( )->collect(
|
|
iv_from = '20260101'
|
|
it_region = VALUE #( ( sign = 'I' option = 'EQ' low = 'SOUTH' ) ) ).
|
|
cl_abap_unit_assert=>assert_equals( exp = 1 act = lines( lt_lines ) ).
|
|
cl_abap_unit_assert=>assert_equals( exp = lv_expected act = lt_lines[ 1 ]-litres ).
|
|
ENDMETHOD.
|
|
ENDCLASS.
|