67 lines
2.8 KiB
ABAP
67 lines
2.8 KiB
ABAP
CLASS {{p}}t16_test DEFINITION PUBLIC FINAL CREATE PUBLIC
|
|
FOR TESTING DURATION SHORT RISK LEVEL HARMLESS.
|
|
PRIVATE SECTION.
|
|
CLASS-DATA go_env TYPE REF TO if_cds_test_environment.
|
|
CLASS-METHODS class_setup.
|
|
CLASS-METHODS class_teardown.
|
|
METHODS setup.
|
|
METHODS total_of_one_farm FOR TESTING.
|
|
METHODS farm_below_limit FOR TESTING.
|
|
METHODS farm_just_above_limit FOR TESTING.
|
|
ENDCLASS.
|
|
|
|
|
|
CLASS {{p}}t16_test IMPLEMENTATION.
|
|
METHOD class_setup.
|
|
go_env = cl_cds_test_environment=>create( i_for_entity = '{{P}}I_MILK_TOTAL' ).
|
|
ENDMETHOD.
|
|
|
|
METHOD class_teardown.
|
|
go_env->destroy( ).
|
|
ENDMETHOD.
|
|
|
|
METHOD setup.
|
|
go_env->clear_doubles( ).
|
|
ENDMETHOD.
|
|
|
|
METHOD total_of_one_farm.
|
|
DATA lt_farm TYPE STANDARD TABLE OF {{p}}farm WITH EMPTY KEY.
|
|
DATA lt_milk TYPE STANDARD TABLE OF {{p}}milk WITH EMPTY KEY.
|
|
lt_farm = VALUE #( ( farm_id = 'A' farmer = 'ANN' region = 'EAST' ) ).
|
|
lt_milk = VALUE #( ( farm_id = 'A' deliv_date = '20240101' litres = '400.0' )
|
|
( farm_id = 'A' deliv_date = '20240102' litres = '150.5' ) ).
|
|
go_env->insert_test_data( lt_farm ).
|
|
go_env->insert_test_data( lt_milk ).
|
|
SELECT SINGLE total_litres, delivery_count FROM {{p}}i_milk_total WHERE farm_id = 'A'
|
|
INTO @DATA(ls_total).
|
|
cl_abap_unit_assert=>assert_equals( exp = CONV decfloat34( '550.5' )
|
|
act = CONV decfloat34( ls_total-total_litres ) ).
|
|
cl_abap_unit_assert=>assert_equals( exp = 2 act = ls_total-delivery_count ).
|
|
ENDMETHOD.
|
|
|
|
METHOD farm_below_limit.
|
|
DATA lt_farm TYPE STANDARD TABLE OF {{p}}farm WITH EMPTY KEY.
|
|
DATA lt_milk TYPE STANDARD TABLE OF {{p}}milk WITH EMPTY KEY.
|
|
lt_farm = VALUE #( ( farm_id = 'B' farmer = 'BOB' region = 'WEST' ) ).
|
|
lt_milk = VALUE #( ( farm_id = 'B' deliv_date = '20240101' litres = '100.0' ) ).
|
|
go_env->insert_test_data( lt_farm ).
|
|
go_env->insert_test_data( lt_milk ).
|
|
SELECT COUNT(*) FROM {{p}}i_milk_total INTO @DATA(lv_rows).
|
|
cl_abap_unit_assert=>assert_equals( exp = 0 act = lv_rows ).
|
|
ENDMETHOD.
|
|
|
|
METHOD farm_just_above_limit.
|
|
DATA lt_farm TYPE STANDARD TABLE OF {{p}}farm WITH EMPTY KEY.
|
|
DATA lt_milk TYPE STANDARD TABLE OF {{p}}milk WITH EMPTY KEY.
|
|
lt_farm = VALUE #( ( farm_id = 'C' farmer = 'CARL' region = 'WEST' ) ).
|
|
lt_milk = VALUE #( ( farm_id = 'C' deliv_date = '20240101' litres = '250.0' )
|
|
( farm_id = 'C' deliv_date = '20240102' litres = '250.5' ) ).
|
|
go_env->insert_test_data( lt_farm ).
|
|
go_env->insert_test_data( lt_milk ).
|
|
SELECT SINGLE total_litres FROM {{p}}i_milk_total WHERE farm_id = 'C'
|
|
INTO @DATA(lv_total).
|
|
cl_abap_unit_assert=>assert_equals( exp = CONV decfloat34( '500.5' )
|
|
act = CONV decfloat34( lv_total ) ).
|
|
ENDMETHOD.
|
|
ENDCLASS.
|