86 lines
3.1 KiB
ABAP
86 lines
3.1 KiB
ABAP
REPORT {{p}}charge_stat.
|
|
|
|
PARAMETERS p_from TYPE d OBLIGATORY.
|
|
PARAMETERS p_to TYPE d OBLIGATORY.
|
|
|
|
CLASS lcl_report DEFINITION FINAL.
|
|
PUBLIC SECTION.
|
|
TYPES:
|
|
BEGIN OF ty_line,
|
|
station TYPE {{p}}charge-station,
|
|
total_kwh TYPE {{p}}charge-energy_kwh,
|
|
sessions TYPE i,
|
|
END OF ty_line,
|
|
tt_line TYPE STANDARD TABLE OF ty_line WITH EMPTY KEY.
|
|
METHODS select_totals
|
|
IMPORTING iv_from TYPE d
|
|
iv_to TYPE d
|
|
RETURNING VALUE(rt_lines) TYPE tt_line.
|
|
METHODS display
|
|
CHANGING ct_lines TYPE tt_line.
|
|
ENDCLASS.
|
|
|
|
CLASS lcl_report IMPLEMENTATION.
|
|
METHOD select_totals.
|
|
SELECT station, SUM( energy_kwh ) AS total_kwh, COUNT( * ) AS sessions
|
|
FROM {{p}}charge
|
|
WHERE session_date >= @iv_from
|
|
AND session_date <= @iv_to
|
|
GROUP BY station
|
|
ORDER BY total_kwh DESCENDING
|
|
INTO CORRESPONDING FIELDS OF TABLE @rt_lines.
|
|
ENDMETHOD.
|
|
|
|
METHOD display.
|
|
TRY.
|
|
cl_salv_table=>factory( IMPORTING r_salv_table = DATA(lo_alv)
|
|
CHANGING t_table = ct_lines ).
|
|
lo_alv->display( ).
|
|
CATCH cx_salv_msg INTO DATA(lx_error).
|
|
MESSAGE lx_error TYPE 'I' DISPLAY LIKE 'E'.
|
|
ENDTRY.
|
|
ENDMETHOD.
|
|
ENDCLASS.
|
|
|
|
START-OF-SELECTION.
|
|
DATA(go_report) = NEW lcl_report( ).
|
|
DATA(gt_lines) = go_report->select_totals( iv_from = p_from iv_to = p_to ).
|
|
go_report->display( CHANGING ct_lines = gt_lines ).
|
|
|
|
CLASS ltc_report DEFINITION FINAL FOR TESTING DURATION SHORT RISK LEVEL HARMLESS.
|
|
PRIVATE SECTION.
|
|
CLASS-DATA go_env TYPE REF TO if_osql_test_environment.
|
|
CLASS-METHODS class_setup.
|
|
CLASS-METHODS class_teardown.
|
|
METHODS totals_per_station FOR TESTING.
|
|
METHODS date_filter FOR TESTING.
|
|
ENDCLASS.
|
|
|
|
CLASS ltc_report IMPLEMENTATION.
|
|
METHOD class_setup.
|
|
go_env = cl_osql_test_environment=>create( i_dependency_list = VALUE #( ( '{{P}}CHARGE' ) ) ).
|
|
DATA lt_charge TYPE STANDARD TABLE OF {{p}}charge WITH EMPTY KEY.
|
|
lt_charge = VALUE #( ( session_id = 1 station = 'A' session_date = '20260101' energy_kwh = 10 )
|
|
( session_id = 2 station = 'A' session_date = '20260102' energy_kwh = 5 )
|
|
( session_id = 3 station = 'B' session_date = '20260101' energy_kwh = 40 ) ).
|
|
go_env->insert_test_data( lt_charge ).
|
|
ENDMETHOD.
|
|
|
|
METHOD class_teardown.
|
|
go_env->destroy( ).
|
|
ENDMETHOD.
|
|
|
|
METHOD totals_per_station.
|
|
DATA(lt_lines) = NEW lcl_report( )->select_totals( iv_from = '20260101' iv_to = '20261231' ).
|
|
cl_abap_unit_assert=>assert_equals( exp = 2 act = lines( lt_lines ) ).
|
|
cl_abap_unit_assert=>assert_equals( exp = 'B' act = lt_lines[ 1 ]-station ).
|
|
cl_abap_unit_assert=>assert_equals( exp = 2 act = lt_lines[ 2 ]-sessions ).
|
|
ENDMETHOD.
|
|
|
|
METHOD date_filter.
|
|
DATA(lt_lines) = NEW lcl_report( )->select_totals( iv_from = '20260102' iv_to = '20261231' ).
|
|
cl_abap_unit_assert=>assert_equals( exp = 1 act = lines( lt_lines ) ).
|
|
cl_abap_unit_assert=>assert_equals( exp = CONV {{p}}charge-energy_kwh( 5 ) act = lt_lines[ 1 ]-total_kwh ).
|
|
ENDMETHOD.
|
|
ENDCLASS.
|